Classification Attribute Declarations Including Inherited Declarations

Get the declarations for classification attributes of the classes in the DEXPI Information Model. For each class, also the inherited declarations are included.

cls_label
Simple label of the class for which the attribute is declared.
decl_label
Simple label of the attribute declaration.
decl_rdl
The RDL reference associated with the attribute declaration.
classification_type_label
Simple label of the classification type of the attribute.
is_proteus_generic_attribute
A boolean indicating if the attribute is represented as a <GenericAttribute> in a DEXPI-compliant Proteus XML file.

SPARQL Query

PREFIX meta: <http://sandbox.dexpi.org/meta/>
PREFIX im: <http://sandbox.dexpi.org/informationmodel/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?cls_label ?decl_label ?decl_rdl ?classification_type_label ?is_generic_attribute
WHERE
{
    ?cls a meta:ModelClass;
        meta:simpleLabel ?cls_label;
        meta:subClassOf* ?super_cls.

    ?super_cls meta:hasDeclaration ?decl.

    ?decl a meta:AttributeDeclaration;
        meta:hasTargetType [
            a meta:ClassificationType;
            meta:simpleLabel ?classification_type_label];
        meta:simpleLabel ?decl_label.

    OPTIONAL
    {
        ?decl meta:rdl ?decl_rdl.
    }

    BIND
    (
        EXISTS
        {
            ?decl meta:proteusImplementation [
                a meta:StandardGenericAttribute]
        }
        AS ?is_generic_attribute
    )
}
ORDER BY ?cls_label ?decl_label

Partial SPARQL Results

The full query result contains 188 rows. The first rows are as follows:

cls_label decl_label decl_rdl classification_type_label is_generic_attribute
AngleBallValve HeatTracingTypeSpecialization http://sandbox.dexpi.org/rdl/HeatTracingTypeSpecialization HeatTracingTypeClassification true
AngleBallValve NumberOfPortsSpecialization http://sandbox.dexpi.org/rdl/NumberOfPortsSpecialization NumberOfPortsClassification true
AngleBallValve OnHoldSpecialization http://sandbox.dexpi.org/rdl/OnHoldSpecialization OnHoldClassification true
AngleBallValve OperationSpecialization http://sandbox.dexpi.org/rdl/OperationSpecialization OperationClassification true
AngleBallValve PipingClassArtefactSpecialization http://sandbox.dexpi.org/rdl/PipingClassArtefactSpecialization PipingClassArtefactClassification true
... ... ... ... ...

Full SPARQL Results

Online

Note

Online results can change! There is no guarantee that these results correspond to version 0.11 of the DEXPI Information Model.

Get results online from DEXPI SPARQL server at http://endpoint.dexpi.org:

Offline

Note

The offline results below are guaranteed to correspond to version 0.11 of the DEXPI Information Model.

Cached results (offline):